LOCATION ponte -250 0
MASK ponte 400 400 400
PATH ponte
ZETA 400 100
LOCALFLAGS SECONDA TERZA
MUSIC PONTE.MSC




COMMENT
After tramping for many a mile, our heroes spot a small village. 
But they find the road obstructed by the roaring waters of a river.
ENDTEXT




ZONE sforzo
TYPE hear
SOUND sforzo.sfx 2
FREQ 23000
ENDZONE




ZONE splashsnd
TYPE hear
SOUND splash.sfx 1
FREQ 11000
ENDZONE




IFCHAR DOUG
ANIMATION dino
FLAGS ACTIVE | CHARACTER
FILE dino.ani
POSITION 0 20
SCRIPT DINO
ENDANIMATION
ENDIF




IFCHAR DINO
ANIMATION doug
FLAGS ACTIVE | CHARACTER
FILE doug.ani
POSITION 20 20
SCRIPT DOUG
ENDANIMATION
ENDIF




ZONE paese
LIMITS 489 50 639 260
LABEL Village
COMMANDS
MUSIC STOP
ENDCOMMANDS
TYPE door
LOCATION paese
STARTPOS 270 120 9
STARTPOS2 260 120 9
ENDZONE




ZONE steppa4
LIMITS 1 100 80 390
LABEL Steppe
COMMANDS
MUSIC STOP
ENDCOMMANDS
TYPE door
LOCATION steppa4
STARTPOS 350 380 0
STARTPOS2 370 380 0
ENDZONE




ZONE acc
COMMANDS
ON dinopietra1
ON dinopietra3
ON dinopietra2
SWAP dino
OFF dougpietra1
OFF dougpietra3
OFF dougpietra2
MOVE 90 290
ENDCOMMANDS
TYPE examine
DESC
Ouch! It's too heavy for me. Dino, you try!
ENDTEXT
ENDZONE




ZONE dougpietra2
LIMITS 200 240 280 290
MOVETO 166 287 18
LABEL Boulder
FLAGS FIXED
COMMANDS
SPEAK acc
ENDCOMMANDS
TYPE get
FILE pietra2.ras
ENDZONE




ZONE dougpietra3
LIMITS 160 220 240 270
MOVETO 166 287 18
LABEL Boulder
FLAGS FIXED
COMMANDS
SPEAK acc
ENDCOMMANDS
TYPE get
FILE pietra3.ras
ENDZONE




ZONE dougpietra1
LIMITS 150 200 230 250
MOVETO 114 269 18
LABEL Boulder
FLAGS FIXED
COMMANDS
SPEAK acc
ENDCOMMANDS
TYPE get
FILE pietra1.ras
ENDZONE




############################################################### DINO




ANIMATION splash2
FLAGS NOMASKED
FILE splash.ani
SCRIPT splash
POSITION -95 90
COMMANDS
OFF splash2
ENDCOMMANDS
ENDANIMATION




ANIMATION dinomasso2
FLAGS NOMASKED
FILE masso1.ani
SCRIPT masso2
POSITION -140 -7
COMMANDS
SET SECONDA
ONMOUSE
OFF dinopietra2
START splash2
ON splash2
ENDCOMMANDS
ENDANIMATION




ZONE masso2
LIMITS 240 335 400 400
FLAGS REMOVE | FIXED
TYPE get
FILE pietra2.ras
ENDZONE




ZONE dinopietra2
LIMITS 200 240 280 290
MOVETO 164 290 18
LABEL Boulder
FLAGS REMOVE
COMMANDS
START dinomasso2
ON dinomasso2
OFFMOUSE
OFF yourself
ENDCOMMANDS
TYPE get
FILE pietra2.ras
ENDZONE




ZONE orano
TYPE examine
DESC
I'd rather lift them in a different order...
ENDTEXT
ENDZONE




#########
################### MASSO 3
#########




ANIMATION splash3
FLAGS NOMASKED
FILE splash.ani
SCRIPT splash
POSITION 20 90
COMMANDS
OFF splash3
ENDCOMMANDS
ENDANIMATION




ZONE masso3
LIMITS 355 335 400 400
FLAGS REMOVE | FIXED
TYPE get
FILE pietra3.ras
ENDZONE




ANIMATION dinomasso3
FLAGS NOMASKED
FILE masso3.ani
SCRIPT masso3
POSITION -180 -30
COMMANDS
SET TERZA
OFF dinopietra3
ONMOUSE
ENDCOMMANDS
ENDANIMATION




ZONE dinopietra3
LIMITS 160 220 240 270
MOVETO 125 265 18
LABEL Boulder
FLAGS REMOVE
COMMANDS
START dinomasso3 FLAGS SECONDA
ON dinomasso3 FLAGS SECONDA
OFF yourself FLAGS SECONDA
OFFMOUSE FLAGS SECONDA
SPEAK orano FLAGS NOSECONDA
ON dinopietra3 FLAGS NOSECONDA
ON dinopietra2 FLAGS NOSECONDA
ENDCOMMANDS
TYPE get
FILE pietra3.ras
ENDZONE




######
############### MASSO 1
######




ANIMATION splash1
FLAGS NOMASKED
FILE splash.ani
SCRIPT splash
POSITION 100 90
COMMANDS
OFF splash1
ENDCOMMANDS
ENDANIMATION








ANIMATION dinomasso1
FLAGS NOMASKED
FILE masso2.ani
SCRIPT masso1
POSITION -195 -35
COMMANDS
SPEAK vienidoug
OFF dinopietra1
ONMOUSE
ENDCOMMANDS
ENDANIMATION




ZONE masso1
LIMITS 455 335 500 400
FLAGS REMOVE | FIXED
TYPE get
FILE pietra1.ras
ENDZONE








ZONE dinopietra1
LIMITS 150 200 230 250
MOVETO 120 260 18
LABEL Boulder
FLAGS REMOVE
COMMANDS
START dinomasso1 FLAGS TERZA
ON dinomasso1 FLAGS TERZA
OFF yourself FLAGS TERZA
OFFMOUSE FLAGS TERZA
SPEAK orano FLAGS NOTERZA
ON dinopietra1 FLAGS NOTERZA
ON dinopietra3 FLAGS NOTERZA
ON dinopietra2 FLAGS NOSECONDA
OFF expietre FLAGS NOTERZA
ENDCOMMANDS
TYPE get
FILE pietra1.ras
ENDZONE




########################################################




ANIMATION guada
SCRIPT guada
COMMANDS
FOLLOWME dino
OFF guadafiume
OFF parladino
ONMOUSE
ENDCOMMANDS
ENDANIMATION




ZONE guadafiume
FLAGS REMOVE
LIMITS 240 300 640 399
LABEL "cross the river"
MOVETO 215 350 18
COMMANDS
START guada
OFFMOUSE
ENDCOMMANDS
TYPE command
ENDZONE




ZONE vienidoug
COMMANDS
SWAP doug
ON guadafiume
OFF parladino
OFF steppa4
ENDCOMMANDS
TYPE examine
DESC
Come on, Doug. We can get across now!
ENDTEXT
ENDZONE




ZONE expietre
LIMITS 150 200 280 290
LABEL Boulders
TYPE examine
DESC
What massive great stones! They must weigh a ton!
ENDTEXT
ENDZONE




ZONE ponte
LIMITS 16 152 525 200
LABEL Bridge
TYPE examine
DESC
Disaster! It's collapsed! How can we get over the river now?
ENDTEXT
ENDZONE




ZONE exvillaggio
LIMITS 489 50 640 140
LABEL Village
TYPE examine
DESC
It seems to be a small village... perhaps there's someone who can help us...
ENDTEXT
ENDZONE




ZONE parladino
FLAGS nowalk
LIMITS dino
LABEL Dino
TYPE speak
FILE doug.tal
DIALOGUE




QUESTION inizio
null
1
ANSWER
We've got to find a way / of getting across this river... I'm sure we'll get some useful information in the village. Have you got any good ideas?
2
ehu
ENDQUESTION




QUESTION ehu
Um... maybe we could swim across...
7
ANSWER
The water's too cold, and the current's too strong. Any other bright ideas?
5
beh
ENDQUESTION




QUESTION beh
Let me see... maybe we could empty the water out with a bucket...
7
ANSWER
What rubbish! That would never work!
4
hai
ENDQUESTION




QUESTION hai
Oh, of course. What an idiot I am! We haven't got a bucket!
9
ENDQUESTION
ENDDIALOGUE
ENDZONE




ZONE EXFIUME
LIMITS 250 200 590 330
LABEL river
COMMANDS
ON RIEMPIBOTT
ENDCOMMANDS
TYPE examine
DESC
That's queer... the river's all full of water!
ENDTEXT
ENDZONE




ZONE RIEMPIBOTT
LIMITS 250 200 590 390
MOVETO 584 316 27
LABEL "FILL THE BOTTLE"
COMMANDS
DROP BOTTIGLIA
ADD ACQUA
ENDCOMMANDS
TYPE COMMAND BOTTIGLIA
ENDZONE




COMMANDS
MUSIC PLAY
MUSIC LOOP 1
ENDCOMMANDS




ENDLOCATION








