@ECHO OFF
ECHO Death Gate CD-ROM
ECHO
ECHO Setup and play for Gravis UltraSound General MIDI
ECHO.
ECHO Press Ctrl-Break if you would like to exit now, otherwise press any key.
ECHO.
PAUSE > NUL
IF NOT "%ULTRASND%" == "" GOTO :OK
echo :   WARNING: The ULTRASND environment variable isn't  :
echo :   present.  Make sure your UltraSound is properly   :
echo :   installed.  Please contact Advanced Gravis for    :
echo :   further technical support. (604) 431-502 Mon-Fri  :
echo :   8am to 4pm.                                       :
GOTO :EXIT
REM
REM check to see if the user has at least version 2.00 of the GUS software
REM
:OK
IF EXIST %ULTRADIR%\MIDI\ACPIANO.PAT GOTO START
echo :   WARNING: You are running out dated UltraSound     :
echo :   patches. Please contact Advanced Gravis to get    :
echo :   the updated software, (604) 431-5020 Mon-Fri      :
echo :   8am to 4pm.                                       :
GOTO :EXIT
:START
ECHO Initializing UltraMID General MIDI patches
ultramid -f -q
REM
REM Find out which configuration file to use
REM
IF EXIST %ULTRADIR%\MIDI\HONKY.PAT GOTO :V206A
ultramid -c -nUM200.ini -d.\
IF ERRORLEVEL 1 GOTO :ABORT
GOTO :PLAY
:V206A
IF NOT EXIST %ULTRADIR%\MIDI\TREMSTR.PAT GOTO :V206
IF NOT EXIST %ULTRADIR%\MIDI\CHARANG.PAT GOTO :V206
IF NOT EXIST %ULTRADIR%\MIDI\ECHOVOX.PAT GOTO :V206
ultramid -c -nUM206A.INI -d.\
IF ERRORLEVEL 1 GOTO :ABORT
GOTO :PLAY
:V206
ultramid -c -nUM206.INI -d.\
IF ERRORLEVEL 1 GOTO :ABORT
GOTO :PLAY

:ABORT
ECHO UltraMID initialization FAILED
ECHO.
echo :   Make sure your UltraSound is properly installed.  :
echo :   Please contact Advanced Gravis for further        :
echo :   technical support. (604) 431-502 Mon-Fri          :
echo :   8am to 4pm.                                       :
GOTO :EXIT

:PLAY
REM
REM Ok, now we're ready to start
REM
ECHO Starting Death Gate
DGATE
REM
REM All done, clean up memory
REM
ECHO Unloading ULTRAMID driver
ultramid -f -q

:EXIT
